ci, tests : use cmake to download models and remove libcurl dependency (#18791)

* ci, tests : use cmake to download models and remove libcurl dependency
* llama_dl_model -> llama_download_model
* use EXPECTED_HASH for robust model downloading
* Move llama_download_model to cmake/common.cmake

Signed-off-by: Adrien Gallouët <angt@huggingface.co>

cmake/common.cmake

@@ -33,3 +33,25 @@ function(llama_add_compile_flags)
         endif()
     endif()
 endfunction()
+
+function(llama_download_model NAME HASH)
+    set(DEST "${CMAKE_BINARY_DIR}/${NAME}")
+    get_filename_component(DEST_DIR "${DEST}" DIRECTORY)
+    file(MAKE_DIRECTORY "${DEST_DIR}")
+    if(NOT EXISTS "${DEST}")
+        message(STATUS "Downloading ${NAME} from ggml-org/models...")
+    endif()
+    file(DOWNLOAD
+        "https://huggingface.co/ggml-org/models/resolve/main/${NAME}?download=true"
+        "${DEST}"
+        TLS_VERIFY ON
+        EXPECTED_HASH ${HASH}
+        STATUS status
+    )
+    list(GET status 0 code)
+    if(NOT code EQUAL 0)
+        list(GET status 1 msg)
+        message(FATAL_ERROR "Failed to download ${NAME}: ${msg}")
+    endif()
+    set(LLAMA_DOWNLOAD_MODEL "${DEST}" PARENT_SCOPE)
+endfunction()